feat(bazel): expose individual .map files for optimized bundles

Currently we do not declare individual file targets/pre-declared outputs
for map files, but we do for `.js` files. This is inconsistent and the
individual `map` files are useful to be "reference-able" when e.g. a
JS mapping size test is configured.

To achieve this we introduce a new rule for filtering outputs. This
rule will become helpful in the future as we often have scenarios where
`$(rootpath X)` cannot be used due to multiple outputs, even though e.g.
a genrule might only be interested in a single file for constructing a
command.

Author: devversion

bazel/BUILD.bazel

@@ -5,6 +5,7 @@ filegroup(
         "expand_template.bzl",
         "extract_js_module_output.bzl",
         "extract_types.bzl",
+        "filter_outputs.bzl",
         "//bazel/api-golden:files",
         "//bazel/app-bundling:files",
         "//bazel/benchmark:files",
@@ -15,6 +16,7 @@ filegroup(
         "//bazel/integration:files",
         "//bazel/karma:files",
         "//bazel/map-size-tracking:files",
+        "//bazel/private:files",
         "//bazel/remote-execution:files",
         "//bazel/spec-bundling:files",
     ],

bazel/app-bundling/index.bzl

@@ -8,6 +8,7 @@ load("@npm//@bazel/terser:index.bzl", "terser_minified")
 load("@npm//prettier:index.bzl", "prettier")
 load("//bazel/esbuild:index.bzl", "esbuild", "esbuild_config")
 load("//bazel:expand_template.bzl", "expand_template")
+load("//bazel:filter_outputs.bzl", "filter_outputs")
 
 def _create_esbuild_minify_options(debug = False):
     # The minify options match with the configuration used by the CLI. The whitespace
@@ -76,9 +77,7 @@ def app_bundle(
     common_terser_options = {
         "visibility": visibility,
         "config_file": "//bazel/app-bundling:terser_config.json",
-        # TODO: Enable source maps for better debugging when `@bazel/terser` pre-declares
-        # JS and map outputs. Tracked with: DEV-120
-        "sourcemap": False,
+        "sourcemap": True,
     }
 
     esbuild(
@@ -94,10 +93,12 @@ def app_bundle(
     )
 
     terser_minified(name = name + ".min", src = name + ".js", **common_terser_options)
-    native.filegroup(name = name + ".min.js", srcs = [name + ".min"], visibility = visibility)
+    filter_outputs(name = name + ".min.js", target = ":%s.min" % name, filters = ["%s.min.js" % name], visibility = visibility)
+    filter_outputs(name = name + ".min.js.map", target = ":%s.min" % name, filters = ["%s.min.js.map" % name], visibility = visibility)
 
     terser_minified(name = name + ".debug.min", src = name + ".debug.js", debug = True, tags = ["manual"], **common_terser_options)
-    native.filegroup(name = name + ".debug.min.js", srcs = [name + ".debug.min"], visibility = visibility, tags = ["manual"])
+    filter_outputs(name = name + ".debug.min.js", target = ":%s.debug.min" % name, filters = ["%s.debug.min.js" % name], visibility = visibility)
+    filter_outputs(name = name + ".debug.min.js.map", target = ":%s.debug.min" % name, filters = ["%s.debug.min.js.map" % name], visibility = visibility)
 
     # For better debugging, we also run prettier on the minified debug bundle. This is
     # necessary as Terser no longer has beautify/formatting functionality.

bazel/app-bundling/test/BUILD.bazel

@@ -36,6 +36,7 @@ jasmine_node_test(
     name = "test",
     data = [
         ":bundle.min.js",
+        ":bundle.min.js.map",
         "@npm//jsdom",
     ],
     # JSDOM should not be bundled because it has workers and dynamic imports.

bazel/filter_outputs.bzl

@@ -0,0 +1,45 @@
+load("//bazel/private:manifest_path.bzl", "get_manifest_path")
+
+def _filter_outputs_impl(ctx):
+    outputs = []
+    target_label = ctx.attr.target.label
+    target_workspace = target_label.workspace_name if target_label.workspace_name else ctx.workspace_name
+    target_package_manifest_path = "%s/%s" % (target_workspace, target_label.package)
+    used_filters = dict()
+
+    for output in ctx.attr.target[DefaultInfo].files.to_list():
+        manifest_path = get_manifest_path(ctx, output)
+        relative_path = manifest_path[len(target_package_manifest_path) + 1:]
+
+        for filter in ctx.attr.filters:
+            if filter == relative_path:
+                used_filters[filter] = True
+                outputs.append(output)
+
+    # If some filters are unused, we report an error as we expect every filter to\
+    # be matched at least once.
+    if len(used_filters) != len(ctx.attr.filters):
+        unused_filters = [f for f in ctx.attr.filters if not used_filters.get(f)]
+        fail("Some filters in `%s` do not match. Unused filters: %s" % (ctx.label, unused_filters))
+
+    return [DefaultInfo(files = depset(outputs))]
+
+filter_outputs = rule(
+    implementation = _filter_outputs_impl,
+    attrs = {
+        "target": attr.label(
+            mandatory = True,
+            doc = "Target for which outputs should be filtered",
+            providers = [DefaultInfo],
+        ),
+        "filters": attr.string_list(
+            mandatory = True,
+            doc = """Outputs to filter from the target. Each filter is expected to match
+              at least once. Filter paths are expected to be relative to the package owning the target.
+            """,
+        ),
+    },
+    doc = """Rule that can be used to filter outputs from a given target.
+      This is useful when a target exposes multiple output files but a single output is only needed.
+    """,
+)

bazel/private/BUILD.bazel

@@ -0,0 +1,7 @@
+package(default_visibility = ["//visibility:public"])
+
+# Make source files available for distribution via pkg_npm
+filegroup(
+    name = "files",
+    srcs = glob(["*"]),
+)

bazel/private/manifest_path.bzl

@@ -0,0 +1,21 @@
+"""Starlark helpers for Bazel manifest paths."""
+
+def get_manifest_path(ctx, file):
+    """Computes the manifest path for the given `File`.
+
+    For example: `../some/file` becomes `<wksp_name>/some/file` or
+                 `../external_wksp/some/file` becomes `external_wksp/some/file`.
+
+    Args:
+      ctx: Rule context
+      file: File for which to retrieve the manifest path.
+    Returns:
+      A manifest path for the given file.
+    """
+
+    # If a short path starts with `../`, then the file is from an external
+    # workspace and we can just strip off the leading segment.
+    if file.short_path.startswith("../"):
+        return file.short_path[3:]
+
+    return "%s/%s" % (ctx.workspace_name, file.short_path)